題 如果信息來自“true”和“false”,我如何在Excel中得到“是”或“否”?


首先,我必須指出我是德國人訪問這個論壇(我在德國網站上找不到任何有用的東西),請原諒我的英語,如果這里和那裡都不好;-)

這是我的“問題”:

我有一個非常廣泛的電子表格,有不同的公式。在R和S列中,我有一個公式,結果會給我“真”或“假”。

現在,我需要一個額外的公式,如果符合以下條件,我將給出“是”或“否”答案:

  • 列R和列S =“真” - >“是”
  • 列R和列S =“假” - >“否”
  • R列不等列S - >“否”

我相信這有一個公式。有人能幫助我嗎? : - /


4
2017-08-25 14:07


起源




答案:


這聽起來很簡單 AND 條件。

=IF(AND(R1,S1),"Yes","No")

12
2017-08-25 14:16



不 - 嘗試過那個:( Excel高亮(R1,S1)如果我添加公式... - Guest089
@ Guest089我不知道這意味著什麼。你是什​​麼意思“亮點”?你是如何使用這個公式的?在一個牢房? - Excellll
@ Guest089您是否嘗試用分號替換我的逗號?我有不同的區域設置。 - Excellll
對了謝謝。就是這樣:)它有效...... - Guest089


如果你的意思是 TRUE/FALSE 代替 "TRUE"/"FALSE" (前者設置為布爾值,後者為字符串),我個人更喜歡前者,並且盡可能將任何輸出保持為布爾格式。將它們保持為布爾是有用的,因為它使得基於它們(並返回它們)編寫公式變得更加容易。我將為下面的幾個變化提供解決方案。使用適合你的任何東西。第2行的解決方案。

情況1:列R&S中的值是布爾值,您需要布爾輸出。

這是最簡單的解決方法。

=AND(R2,S2)

情況2:R&S列中的值是布爾值,您需要字符串輸出。

只要  更複雜。

=IF(AND(R2,S2),"Yes","No")

情況3:列R&S中的值是字符串,您需要布爾輸出。

這開始展示了使用布爾輸出而不是字符串的優勢。

=AND(R2="TRUE",R2=S2)

情況4:列R&S中的值是字符串,您需要布爾輸出。

最後,最不可取的(恕我直言)情況和解決方案。

=IF(AND(R2="TRUE",R2=S2),"Yes","No")

如果一個是布爾值而另一個不是布爾值會更糟,但你現在可能已經明白了。


以下是所有上述操作的屏幕截圖。 A列和B列是R&S的替身,其值為布爾格式。 F&G列是R&S的替身,其價值是字符串。 C列顯示上述案例1中解決方案的示例輸出,案例2為D,案例3為H,案例4為I.

enter image description here


最後,這裡有一組公式應該涵蓋所有真/假輸入變體。

布爾輸出。

=AND(UPPER(TEXT(R2,""))="TRUE",UPPER(TEXT(R2,""))=UPPER(TEXT(S2,"")))

字符串輸出。

=IF(AND(UPPER(TEXT(R2,""))="TRUE",UPPER(TEXT(R2,""))=UPPER(TEXT(S2,""))),"Yes","No")

這應該解釋以下所有情況:

  • R&S都是布爾值
  • R&S都是字符串
  • 一列是布爾值,另一列是字符串
  • 列之間存在大小寫不匹配(例如:列R表示“TRUE”,其中列S表示“true”)

4
2017-08-25 14:21



我的意思是真/假......我的公式在R中= IF($ O $ 4:$ O $ 1080> 0; TRUE; FALSE)仍然,解決方案不起作用:( - Guest089
好吧,看起來這可能部分是由於地區差異造成的。用分號替換我的解決方案中的逗號。另外,S的公式是什麼? - Iszi